Sage Tutorial for Advanced 2d Plotting
This Sage worksheet is one of the tutorials developed for the MAA PREP Workshop "Sage: Using Open-Source Mathematics Software with Undergraduates" (funding provided by NSF DUE 0817071). It is licensed under the Creative Commons Attribution-ShareAlike 3.0 license (CC BY-SA).
Thanks to Sage's integration of projects like matplotlib, Jmol, and Tachyon, Sage has comprehensive plotting capabilities. This pair of worksheets aims to go more in depth with them than previous tutorials. This worksheet consists of the following sections:
This tutorial assumes that one is familiar with the basics of Sage, such as evaluating a cell by clicking the "evaluate" link, or by pressing Shift-Enter (hold down Shift while pressing the Enter key).
Cartesian Plots
A simple quadratic is easy.
{{{id=3|
plot(x^2, (x,-2,2))
///
}}}
You can combine "plot objects" by adding them.
{{{id=6|
regular = plot(x^2, (x,-2,2), color= 'purple')
skinny = plot(4*x^2, (x,-2,2), color = 'green')
regular + skinny
///
}}}
Problem: Plot a green $y=\sin(x)$ together with a red $y=2\,\cos(x)$. (Hint: you can use "pi" as part of your range.)
{{{id=12|
///
}}}
Boundaries of a plot can be specified, in addition to the overall size.
{{{id=9|
plot(1+e^(-x^2), xmin=-2, xmax=2, ymin=0, ymax=2.5, figsize=10)
///
}}}
Problem: Plot $y=5+3\,\sin(4x)$ with suitable boundaries.
{{{id=52|
///
}}}
You can add lots of extra information.
{{{id=11|
exponential = plot(1+e^(-x^2), xmin=-2, xmax=2, ymin=0, ymax=2.5)
max_line = plot(2, xmin=-2, xmax=2, linestyle='-.', color = 'red')
min_line = plot(1, xmin=-2, xmax=2, linestyle=':', color = 'red')
exponential + max_line + min_line
///
}}}
You can fill regions with transparent color, and thicken the curve. This example uses several options to fine-tune our graphic.
{{{id=15|
exponential = plot(1+e^(-x^2), xmin=-2, xmax=2, ymin=0, ymax=2.5, fill=0.5, fillcolor='grey', fillalpha=0.3)
min_line = plot(1, xmin=-2, xmax=2, linestyle='-', thickness= 6, color = 'red')
exponential + min_line
///
}}}
{{{id=177|
sum([plot(x^n,(x,0,1),color=rainbow(5)[n]) for n in [0..4]])
///
}}}
Problem: Create a plot showing the cross-section area for the following solid of revolution problem: Consider the area bounded by $y=x^2-3x+6$ and the line $y=4$. Find the volume created by rotating this area around the line $y=1$.
{{{id=19|
///
}}}
Parametric Plots
A parametric plot needs a list of two functions of the parameter; in Sage, we use square brackets to delimit the list. Notice also that we must declare $t$ as a variable first. Because the graphic is slightly wider than it is tall, we use the 'aspect_ratio' option (such options are called keywords) to ensure the axes are correct for how we want to view this object.
{{{id=17|
var('t')
parametric_plot([cos(t) + 3 * cos(t/9), sin(t) - 3 * sin(t/9)], (t, 0, 18*pi), fill = True, aspect_ratio=1)
///
}}}
Problem: These parametric equations will create a hypocycloid,
$$x(t)=17\cos(t)+3\cos(17t/3)$$
$$y(t)=17\sin(t)-3\sin(17t/3)$$
Create this as a parametric plot.
{{{id=34|
///
}}}
Sage automatically plots a 2d or 3d plot, and a curve or a surface, depending on how many variables and coordinates you specify.
{{{id=89|
var('t')
parametric_plot((t^2,sin(t)), (t,0,pi))
///
}}}
{{{id=80|
var('t')
parametric_plot((t^2,sin(t),cos(t)), (t,0,pi))
///
}}}
{{{id=51|
var('t,r')
parametric_plot((t^2,sin(r*t),cos(r*t)), (t,0,pi),(r,-1,1))
///
}}}
Polar Plots
Sage can also do polar plots.
{{{id=28|
polar_plot(2 + 2*cos(x), (x, 0, 2*pi), color=hue(0.5), thickness=4)
///
}}}
Although they aren't essential, many of these examples try to demonstrate things like coloring, fills, and shading to give you a sense of the possibilities.
More than one polar curve can be specified in a list (square brackets). Notice the automatic graded shading of the fill color.
{{{id=29|
var('t')
polar_plot([cos(4*t) + 1.5, 0.5 * cos(4*t) + 2.5], (t, 0, 2*pi), color='black', thickness=2, fill=True, fillcolor='orange')
///
}}}
Problem: Create a plot for the following problem. Find the area that is inside the circle $r=2$, but outside the cardiod $2+2\cos(\theta)$.
{{{id=31|
///
}}}
{{{id=55|
///
}}}
{{{id=54|
///
}}}
Interactive Graphics
It may be of interest to see all these things put together in a very nice pedagogical graphic. Even though this is fairly advanced (and so we hide the code) it is not as difficult as you might think to put together.
{{{id=47|
%hide
%auto
html('Sine and unit circle (by Jurgis Pralgauskis)
inspired by this video' )
# http://www.sagemath.org/doc/reference/sage/plot/plot.html
radius = 100 # scale for radius of "unit" circle
graph_params = dict(xmin = -2*radius, xmax = 360,
ymin = -(radius+30), ymax = radius+30,
aspect_ratio=1,
axes = False
)
def sine_and_unit_circle( angle=30, instant_show = True, show_pi=True ):
ccenter_x, ccenter_y = -radius, 0 # center of cirlce on real coords
sine_x = angle # the big magic to sync both graphs :)
current_y = circle_y = sine_y = radius * sin(angle*pi/180)
circle_x = ccenter_x + radius * cos(angle*pi/180)
graph = Graphics()
# we'll put unit circle and sine function on the same graph
# so there will be some coordinate mangling ;)
# CIRCLE
unit_circle = circle((ccenter_x, ccenter_y), radius, color="#ccc")
# SINE
x = var('x')
sine = plot( radius * sin(x*pi/180) , (x, 0, 360), color="#ccc" )
graph += unit_circle + sine
# CIRCLE axis
# x axis
graph += arrow( [-2*radius, 0], [0, 0], color = "#666" )
graph += text("$(1, 0)$", [-16, 16], color = "#666")
# circle y axis
graph += arrow( [ccenter_x,-radius], [ccenter_x, radius], color = "#666" )
graph += text("$(0, 1)$", [ccenter_x, radius+15], color = "#666")
# circle center
graph += text("$(0, 0)$", [ccenter_x, 0], color = "#666")
# SINE x axis
graph += arrow( [0,0], [360, 0], color = "#000" )
# let's set tics
# or http://aghitza.org/posts/tweak_labels_and_ticks_in_2d_plots_using_matplotlib/
# or wayt for http://trac.sagemath.org/sage_trac/ticket/1431
# ['$-\pi/3$', '$2\pi/3$', '$5\pi/3$']
for x in range(0, 361, 30):
graph += point( [x, 0] )
angle_label = ". $%3d^{\circ}$ " % x
if show_pi: angle_label += " $(%s\pi) $"% x/180
graph += text(angle_label, [x, 0], rotation=-90,
vertical_alignment='top', fontsize=8, color="#000" )
# CURRENT VALUES
# SINE -- y
graph += arrow( [sine_x,0], [sine_x, sine_y], width=1, arrowsize=3)
graph += arrow( [circle_x,0], [circle_x, circle_y], width=1, arrowsize=3)
graph += line(([circle_x, current_y], [sine_x, current_y]), rgbcolor="#0F0", linestyle = "--", alpha=0.5)
# LABEL on sine
graph += text("$(%d^{\circ}, %3.2f)$"%(sine_x, float(current_y)/radius), [sine_x+30, current_y], color = "#0A0")
# ANGLE -- x
# on sine
graph += arrow( [0,0], [sine_x, 0], width=1, arrowsize=1, color='red')
# on circle
graph += disk( (ccenter_x, ccenter_y), float(radius)/4, (0, angle*pi/180), color='red', fill=False, thickness=1)
graph += arrow( [ccenter_x, ccenter_y], [circle_x, circle_y],
rgbcolor="#cccccc", width=1, arrowsize=1)
if instant_show:
show (graph, **graph_params)
return graph
#####################
# make Interaction
######################
@interact
def _( angle = slider([0..360], default=30, step_size=5,
label="Pasirinkite kampą: ", display_value=True) ):
sine_and_unit_circle(angle, show_pi = False)
///
Sine and unit circle (by Jurgis Pralgauskis)
inspired by this video
}}}
Plotting Data Points
Sometimes one wishes to simply plot data. Here, we demonstrate several ways of plotting points and data via the simple approximation to the Fibonacci numbers given by
$$F_n=\frac{1}{\sqrt{5}}\left(\frac{1+\sqrt{5}}{2}\right)^n\; ,$$
which is quite good after about $n=5$.
First, we notice that the Fibonacci numbers are built in.
{{{id=61|
fibonacci_sequence(6)
///
}}}
{{{id=62|
list(fibonacci_sequence(6))
///
[0, 1, 1, 2, 3, 5]
}}}
{{{id=60|
list(enumerate(fibonacci_sequence(6)))
///
[(0, 0), (1, 1), (2, 1), (3, 2), (4, 3), (5, 5)]
}}}
In this cell, we just define the numbers and coordinate pairs we are about to plot.
{{{id=56|
fibonnaci = list(enumerate(fibonacci_sequence(6)))
f(n)=(1/sqrt(5))*((1+sqrt(5))/2)^n
asymptotic = [(i, f(i)) for i in range(6)]
///
}}}
{{{id=137|
fibonnaci
///
[(0, 0), (1, 1), (2, 1), (3, 2), (4, 3), (5, 5)]
}}}
{{{id=138|
asymptotic
///
[(0, 1/5*sqrt(5)), (1, 1/10*(sqrt(5) + 1)*sqrt(5)), (2, 1/20*(sqrt(5) + 1)^2*sqrt(5)), (3, 1/40*(sqrt(5) + 1)^3*sqrt(5)), (4, 1/80*(sqrt(5) + 1)^4*sqrt(5)), (5, 1/160*(sqrt(5) + 1)^5*sqrt(5))]
}}}
And here we plot not just the two sets of points, but also use several of the documented options for plotting points; the choice of markers for different data is particularly helpful for generating publishable graphics.
{{{id=36|
fib_plot=scatter_plot(fibonnaci, facecolor='red', marker='o',markersize=40)
asy_plot = line(asymptotic, marker='D',color='black',thickness=2)
show(fib_plot+asy_plot, aspect_ratio=1)
///
}}}
{{{id=45|
///
}}}
Contour Plots
Contour plotting can be very useful when trying to get a handle on multivariable functions, as well as modeling. The basic syntax is essentially the same as for 3D plotting - simply an extension of the 2D plotting syntax.
{{{id=118|
f(x,y)=y^2+1-x^3-x
contour_plot(f, (x,-pi,pi), (y,-pi,pi))
///
}}}
We can change colors, specify contours, label curves, and many other things. When there are many levels, the 'colorbar' keyword becomes quite useful for keeping track of them. Notice that, as opposed to many other options, it can only be 'True' or 'False' (corresponding to whether it appears or does not appear).
{{{id=121|
contour_plot(f, (x,-pi,pi), (y,-pi,pi),colorbar=True,labels=True)
///
}}}
This example is fairly self-explanatory, but demonstrates the power of formatting, labeling, and the wide variety of built-in color gradations (colormaps or 'cmap's). The strange-looking construction corresponding to 'label_fmt' is a Sage/Python data type called a dictionary, and turns out to be useful for more advanced Sage use; it consists of pairs connected by a colon, all inside curly braces.
{{{id=117|
contour_plot(f, (x,-pi,pi), (y,-pi,pi), contours=[-4,0,4], fill=False, cmap='cool', labels=True, label_inline=True, label_fmt={-4:"low", 0:"medium", 4: "hi"}, label_colors='black')
///
}}}
Implicit plots are a special type of contour plot (they just plot the zero contour).
{{{id=139|
f(x,y)
///
-x^3 + y^2 - x + 1
}}}
{{{id=116|
implicit_plot(f(x,y)==0,(x,-pi,pi),(y,-pi,pi))
///
}}}
{{{id=133|
///
}}}
A density plot is like a contour plot, but without discrete levels.
{{{id=132|
x,y = var('x,y')
density_plot(f, (x, -2, 2), (y, -2, 2))
///
}}}
Somtimes contour plots can be a little misleading (which makes for a great classroom discussion about the problems of ignorantly relying on technology). Here we combine a density plot and contour plot to show even better what is happening with the function.
{{{id=134|
density_plot(f,(x,-2,2),(y,-2,2))+contour_plot(f,(x,-2,2),(y,-2,2),fill=False,labels=True,label_inline=True,cmap='jet')
///
}}}
Note: mention something about the options
{{{id=142|
contour_plot.options
///
{'labels': False, 'linestyles': None, 'frame': True, 'axes': False, 'plot_points': 100, 'linewidths': None, 'colorbar': False, 'contours': None, 'legend_label': None, 'fill': True}
}}}
{{{id=141|
contour_plot.options["fill"]=False
///
}}}
{{{id=150|
contour_plot.options
///
{'labels': False, 'linestyles': None, 'frame': True, 'axes': False, 'plot_points': 100, 'linewidths': None, 'colorbar': False, 'contours': None, 'legend_label': None, 'fill': False}
}}}
{{{id=149|
contour_plot(f,(x,-2,2),(y,-2,2))
///
}}}
{{{id=148|
contour_plot.defaults()
///
{'labels': False, 'linestyles': None, 'frame': True, 'axes': False, 'plot_points': 100, 'linewidths': None, 'colorbar': False, 'contours': None, 'legend_label': None, 'fill': True}
}}}
{{{id=144|
///
}}}
{{{id=145|
///
}}}
Vector fields
The syntax for vector fields is very similar to other multivariate constructions. Notice that the arrows are scaled appropriately, and colored by length in the 3D case.
{{{id=67|
var('x,y')
plot_vector_field((-y+x,y*x),(x,-3,3),(y,-3,3))
///
}}}
{{{id=39|
var('x,y,z')
plot_vector_field3d((-y,-z,x), (x,-3,3),(y,-3,3),(z,-3,3))
///
}}}
3d vector field plots are ideally viewed with 3d glasses (right-click on the plot and select "Style" and "Stereographic")
{{{id=147|
///
}}}
{{{id=146|
///
}}}
Complex Plots
We can plot functions of complex variables, where the magnitude is indicated by the brightness (black=0) and the argument is indicated by the hue (red=positive real).
{{{id=66|
f(z) = exp(z) #z^5 + z - 1 + 1/z
complex_plot(f, (-5,5),(-5,5))
///
}}}
Region plots
These plot where an expression is true, and are useful for plotting inequalities.
{{{id=94|
region_plot(cos(x^2+y^2) <= 0, (x, -3, 3), (y, -3, 3),aspect_ratio=1)
///
}}}
We can get fancier options as well.
{{{id=97|
region_plot(sin(x)*sin(y) >= 1/4, (x,-10,10), (y,-10,10), incol='yellow', bordercol='black', borderstyle='dashed', plot_points=250,aspect_ratio=1)
///
}}}
{{{id=96|
///
}}}
Builtin Graphics Objects
Sage includes a variety of built-in graphics objects. These are particularly useful for adding to one's plot certain objects which are difficult to describe with equations, but which are basic geometric objects nonetheless. In this section we will try to demonstrate the syntax of some of the most useful of them; for most of the the contextual (remember, append '?') help will give more details.
Points
To make one point, a coordinate pair suffices.
{{{id=171|
point((3,5))
///
}}}
It doesn't matter how multiples points are generated; they must go in as input via a list (square brackets). Here, we demonstrate the hard (but naive) and easy (but a little more sophisticated) way to do this.
{{{id=173|
f(x)=x^2
points([(0,f(0)), (1,f(1)), (2,f(2)), (3,f(3)), (4,f(4))])
///
}}}
{{{id=63|
points([(x,f(x)) for x in range(5)])
///
}}}
Sage tries to tell how many dimensions you are working in automatically.
{{{id=136|
f(x,y)=x^2-y^2
points([(x,y,f(x,y)) for x in range(5) for y in range(5)])
///
}}}
Lines
The syntax for lines is the same as that for points, but you get... well, you get connecting lines too!
{{{id=83|
f(x)=x^2
line([(x,f(x)) for x in range(5)])
///
}}}
Balls
Sage has disks and spheres of various types available. Generally the center and radius are all that is needed, but other options are possible.
{{{id=81|
circle((0,1),1,aspect_ratio=1)
///
}}}
{{{id=176|
disk((0,0), 1, (pi, 3*pi/2), color='yellow',aspect_ratio=1)
///
}}}
Arrows
{{{id=86|
arrow((0,0), (1,1))
///
}}}
{{{id=64|
///
}}}
Polygons
Polygons will try to complete themselves and fill in the interior; otherwise the syntax is fairly self-evident.
{{{id=68|
polygon([[0,0],[1,1],[1,2]])
///
}}}
Text
In 2d, one can typeset mathematics using the 'text' command. This can be used to finetune certain types of labels. Unfortunately, in 3D the text is just text.
{{{id=82|
var('x')
text('$\int_0^2 x^2\, dx$', (0.5,2))+plot(x^2,(x,0,2),fill=True)
///
}}}
Saving Plots
We can save 2d plots to many different formats. Sage can determine the format based on the filename for the image.
{{{id=71|
p=plot(x^2,(x,-1,1))
p
///
}}}
{{{id=152|
p.save('my_plot.png')
///
}}}
{{{id=153|
p.save('my_plot.pdf')
///
}}}
{{{id=155|
p.save('my_plot.svg')
///
}}}
{{{id=72|
///
}}}